Fuel 1.9 is already loaded in Pharo 2.0. The default packages work out of the box in Pharo 1.1.1, 1.1.2, 1.2, 1.3, 1.4, 2.0 and Squeak 4.1, 4.2, 4.3, 4.4.

Default

For most users should be enough to install just the default packages:

Gofer it
    url: 'http://smalltalkhub.com/mc/Pharo/Fuel/main';
    package: 'ConfigurationOfFuel';
    load.
((Smalltalk at: #ConfigurationOfFuel) project version: '1.9') 
    load.

Squeak

In Squeak 4.1, 4.2, 4.3, 4.4, you can either find it in SqueakMap, or evaluate:

(Installer mc http: 'http://smalltalkhub.com/mc/Pharo/Fuel/main')
    project: 'Fuel';
    install: 'ConfigurationOfFuel-MaxLeske.178'.
(Smalltalk at: #ConfigurationOfFuel) load.

Basic demo

Open the Transcript and evaluate code below in a Workspace.

| serializedArray materializedArray |
serializedArray := 
    Array 
        with: (Set with: 42)
        with: Transcript
        with: [:aString | Transcript show: aString; cr ].

"Store (serialize)"
FLSerializer serialize: serializedArray toFileNamed: 'demo.fl'. 

"Load (materialize)"
materializedArray := FLMaterializer materializeFromFileNamed: 'demo.fl'. 

Transcript
	show: 'The sets are equal: ';
	show: serializedArray first = materializedArray first;
	cr;
	show: 'But not the same: ';
	show: serializedArray first ~~ materializedArray first;
	cr;
	show: 'The global value Transcript is the same: ';
	show: serializedArray second == materializedArray second;
	cr.
materializedArray third 
	value: 'The materialized block closure can be properly evaluated.'.